钢轨是铁路线路运营的重要技术装备，在日常运营维护过程中，因钢轨病害伤损更换需要对其进行吊装转运，但科学的吊装方式对保护钢轨轨件有积极的作用。本文利用ANSYS有限元分析软件对吊装点位的选择进行了简要分析。
一、计算模型及参数1.钢轨吊装计算简图
计算简图
钢轨截面
2.分析参数的选择
⑴重力加速度：9800mm/s^2
⑵钢轨：CHN60，60kg/m，弹性模量：2.06×10^5MPa,泊松比为0.3，密度：7.85×10^-9t/mm^3，计算长度45m。
⑶ANSYS分析使用的单元：Cable280索单元模拟吊装索；BEAM188梁单元模拟钢轨。
CABLE280
CABLE280是三维的二次三节点线单元，单元几何构成图中包括I、J、K、L四个节点，其中节点L为方位节点，可省略。每个节点有三个自由度：节点x、y和z方向的平动。即其不受弯矩，只有平移自由度，计算效率高。
该单元支持的技术包括：生死单元、初始状态、大变形、大应变、线性摄动、非线性稳定、应力刚化，与其他Link单元不同，该单元不支持实常数的输入。
BEAM188
BEAM188适用于分析细长的梁。基于Timoshenko梁理论的具有扭切变形效果。BEAM188是一个二节点的三维线性梁。BEAM188在每个节点上有6或7个自由度，（自由度）数目的变化是由KEYOPT(1)来控制的。当KEYOPT(1)=0时(默认),每节点有6个自由度。分别是沿x,y,z的位移及绕其的转动。当KEYOPT(1)=1时,会添加第七个自由度(翘曲量)。此元素能很好的应用于线性（分析），大偏转，大应力的非线性（分析）。
BEAM188包含应力刚度，在默认情况下，在某些分析中由NLGEOM来打开。在进行弯曲（flexural）,侧向弯曲（lateral）,和扭转稳定性（torsionalstability）分析时，应力刚度应该是被打开的。BEAM188能够采用SECTYPE,SECDATA,SECOFFSET,SECWRITE,和SECREAD来定义任何截面（形状），弹性（elasticity）,蠕变（creep）,和塑性（plasticity）模型都是允许的(不考虑次截面形状)。
3.ANSYS分析的APDL代码
!!42#长大轨件-吊装钢轨的简单计算
FINISH$/CLEAR!$/PREP7
/FILNAME,Structure,1!定义工作文件名。
/PREP7!进入前处理模块:定义模型
H0=2E3!吊臂端与吊钩的距离
H=0.7e3!吊钩与槽钢的垂直距离
QL=45e3!吊装轨件的长度
X1=4.9e3
X2=6e3
X4=X2!6e3
X5=X1!4.9e3
X3=QL-X1-X2-X4-X5
L0=0
L1=X1
L2=X1+X2
L2_Z_3=X1+X2+X3/2
L3=X1+X2+X3
L4=X1+X2+X3+X4
L5=X1+X2+X3+X4+X5
K,1,(L1+X2/2),(H+H0)!定义各个结点!单位:m
K,2,(L3+X4/2),(H+H0)!定义各个结点!单位:m
K,3,(L1+X2/2),H!定义各个结点!单位:m
K,4,(L3+X4/2),H!定义各个结点!单位:m
K,5,L0,0
K,6,L1,0
K,7,L2,0
K,8,L2_Z_3,0!X方向位移为0的约束点（中间点）
K,9,L3,0!调整间距的节点
K,10,L4,0!调整间距的节点
K,11,L5,0!调整间距的节点
!系杆定义
ET,1,Cable280!定义第一类单元为二维杆单元Cable280索单元（高阶）
MP,EX,1,2.06E8!定义第一类材料弹性模量EX
MP,PRXY,1,0.3!泊松常数
MP,DENS,1,7.85e-20!绳子的密度，单位：Kg/
SECTYPE,1,link
SECDATA,7.065e3!单位：m㎡,直径3cm
TYPE,1!使用第一类单元
MAT,1!使用第一类材料
SECNUM,1!设定随后梁单元划分将要使用的截面编号
L,1,3
L,2,4
L,3,6!画索
L,3,7
L,4,9!画索
L,4,10
!梁定义
ET,2,BEAM188!定义第2类单元为梁模型BEAM188
MP,EX,2,2.06E5!定义第一类材料弹性模量EX单位：Pa
MP,PRXY,2,0.3!泊松常数
MP,DENS,2,7.85e-9!梁的密度，单位：t/mm3
SECTYPE,2,BEAM,MESH!选项，自定义梁截面
SECREAD,CHN60,SECT,,MESH!选项，读入梁截面
TYPE,2!使用第2类单元
MAT,2!使用第2类材料
SECNUM,2!设定随后梁单元划分将要使用的截面编号
L,5,6!画梁
L,6,7
L,7,8
L,8,9
L,9,10
L,10,11
LSEL,ALL
LSEL,S,LINE,,1,6,1!选择生成的线
CM,GSUO,LINE!将钢索线设置组，组名GSUO
LSEL,S,LINE,,7,12,1!选择生成的线
CM,BDL,LINE!将钢索线设置组，组名BDL
!索单元划分
LSEL,S,,,GSUO
SECNUM,1
LATT,1,,1,GSUO
LESIZE,GSUO,,,30,
LMESH,ALL
!梁单元划分
!K,NPT,X,Y,Z
K,5000,0,10,0
LSEL,S,,,BDL
SECNUM,2
!LATT,MAT,REAL,TYPE,--,KB,KE,SECNUM用这个命令，工字模型的z轴指向KB
LATT,2,,2,,5000,,2!属性赋值给几何模型
LESIZE,BDL,,,50,
LMESH,ALL
ALLSEL,ALL!选择所有项目
SECPLOT,2!图显截面和截面特性
!FINISH!退出前处理模块
!OUTPR,BASIC,ALL!在输出结果中，列出元素的结果
KSEL,ALL
KD,1,ALL,!约束1号结点的所有结点位移分量
KD,1,ROTX,0
KD,1,ROTY,0
KD,1,UX,0
KD,1,UY,0
KD,1,UZ,0
KD,2,ALL,!约束2号结点的所有结点位移分量
KD,2,ROTX,0
KD,2,ROTY,0
KD,2,UX,0
KD,2,UY,0
KD,2,UZ,0
KSEL,ALL
KD,ALL,UZ
KD,8,UX,0!中间点X方向位移为0
!施加初应力,Cable280索单元（高阶）需要施加预应力，计算才收敛
esel,s,ename,,280
inistate,set,csys,elem
inistate,set,dtyp,stre
inistate,define,,,,,10
ALLSEL,ALL!选择所有项目
D,ALL,UZ,0
D,ALL,ROTY,0
D,ALL,ROTX,0
/SOLU!进入求解模块:定义力和位移边界条件,并求解
ANTYPE,STATIC!申明分析类型是静力分析
ALLSEL,ALL
nsubst,100
time,1
cnvtol,m,-1
autots,on!打开自动时间步长
ACEL,,9800!Y方向的重力
SOLVE!发出求解指令
FINISH!退出求解模块
二、计算分析将编写ANSYS的APDL代码设置好参数后进行计算，过程如图所示：
根据实际情况选择吊索的长度及吊装点位的固定位置。进行分析：
1.计算工况：X1=4.9m，X2=6m，X3=23.2m，H=0.7m的变形情况如下图所示：轨端最大上扬167mm/轨跨中部最大下挠215mm。
2.计算工况：X1=5.2m，X2=6m，X3=22.6m，H=0.7m的变形情况如下图所示：轨端最大上扬131mm/轨跨中部最大下挠164mm。
3.计算工况：X1=5.5m，X2=6m，X3=22m，H=0.7m的变形情况如下图所示：轨端最大上扬116mm/轨跨中部最大下挠145mm。
1.根据吊装钢轨的长度及吊索的配置情况，根据计算选择合适的吊点，确保长大钢轨轨件在吊装过程中受力变形满足要求，钢轨不产生过大塑性变形。
2.在运营线路吊装，还应考虑吊索的变形，以及接触网导高与吊臂仰角的限制，确定吊索的长度，避免产生空间不足而无法正常起吊，或者产生吊臂与接触网意外触碰风险。
3.对于高速用轨的吊装需严格遵守钢轨吊装安全操作规程，防止跌落及碰伤。